Lexoni vlerat në një grup Fortran nga rreshti tjetër pas një ndeshjeje vargu

Unë e rishkruaja përgjigjen time për të qenë më e përgjithshme. Ky kod do të trajtojë linja të shumta numrash të plotë midis një rreshti me nset=bf1 dhe çdo rreshti tjetër që fillon '*'.

Për shkak se linjat e inteve mund të ndryshojnë në gjatësi, një grup int 2D është i papërshtatshëm. Në vend të kësaj, unë po ruaj të gjitha int-et në një grup 1D dhe ruaj indeksin e grupit të çdo rreshti të ri.

Për të shmangur leximin e çdo gjëje dy herë, unë po rris madhësinë e vargjeve në fluturim nëse është e nevojshme.

Vini re se nëse përpiluesi juaj nuk e mbështet MOVE_ALLOC (Fortran 2003), atëherë do t'ju duhet thjesht të zëvendësoni secilën thirrje me një grup 'shpërndaj, shpërndaj, shpërndaj'.

program nset_parser
    implicit none

    INTEGER ::  ios,l,val, i, n, nlines, comma_idx, next_idx
    INTEGER, ALLOCATABLE :: my_ints(:), line_starts(:), work_ints(:)
    character(len=80) :: file_name = 'code_check.inp'
    character (len=*), parameter :: search_str = "bf1"
    character(len=5096) :: input_line
    character(len=10) :: keyword
    logical :: h_nset=.false.

    l = len(search_str)

    ALLOCATE(line_starts(10), my_ints(1000))
    next_idx = 1
    nlines = 0

    open(unit=10, file=file_name, status="old", action='read') ! open file
    DO 

      ! Read and adjust the line
      read(10, '(a)',iostat=ios) input_line
      if (ios /=0) exit
      input_line = adjustl(input_line)   

      ! Ignore blank lines
      IF(LEN(TRIM(input_line))==0) CYCLE

      ! This section picks up any line beginning *
      ! and either sets or unsets h_nset
      IF (input_line(1:1) == '*' .AND. input_line(2:2) /= '*') THEN  ! check if it is a comment line or data line

        ! Use of keyword below is a little unsafe if
        ! keywords can be longer than 10 chars (the length of 'keyword')
        ! Instead, better to check if input_line(2:5) == Nset
        ! I left it like this in case you want to be able to check multiple
        ! keywords or something.
        comma_idx = INDEX(input_line, ',')
        keyword = input_line(2:comma_idx-1)

        IF (TRIM(keyword) == 'Nset') THEN
          val = INDEX(input_line, search_str)
          IF (val /= 0) THEN
            h_nset=.TRUE.  ! Switch on when nset=bf1 line is found
            CYCLE
          END IF
        END IF
        h_nset = .FALSE.  ! Only reach this point if we are in a * line which isn't nset=bf1
      END IF

      IF(h_nset) THEN
        n = COUNT(TRANSFER(input_line, 'a', LEN(input_line)) == ",") + 1 !cast to chars and count occurrence of comma
        nlines = nlines + 1

        ! Double size of arrays on the fly if necessary
        IF(nlines > SIZE(line_starts)) THEN
          ALLOCATE(work_ints(nlines * 2))
          work_ints(1:SIZE(line_starts)) = line_starts
          CALL MOVE_ALLOC(work_ints, line_starts)
        END IF
        IF(next_idx+n > SIZE(my_ints)) THEN
          ALLOCATE(work_ints(2*SIZE(my_ints)))
          work_ints(1:SIZE(my_ints)) = my_ints
          CALL MOVE_ALLOC(work_ints, my_ints)
        END IF

        line_starts(nlines) = next_idx
        READ(input_line, *) my_ints(next_idx:next_idx+n-1)
        next_idx = next_idx + n
      END IF
    END DO
    close(10)

    ! This helps with the printing below
    line_starts(nlines+1) = line_starts(nlines) + n

    DO i=1, nlines
      PRINT *, my_ints(line_starts(i):line_starts(i+1)-1)
    END DO
  end program nset_parser